@echo off
setlocal enabledelayedexpansion
REM 声明采用UTF-8编码
chcp 65001

echo ============================
echo 图种制作脚本  2025.6.23
echo ============================
echo 本脚本用于将图片和压缩包合并为图种文件
echo ============================
echo lgwnf.github.io

:input_image
echo 请输入一张PNG或JPG图片的路径（可直接通过拖动文件放入，请注意文件名与路径中不要包含空格），并以回车结束：
set /p imagePath=


if not exist "%imagePath%" (
    echo 图片路径不存在，请检查后重试。
    goto input_image
)

if /i not "%imagePath:~-4%"==".png" if /i not "%imagePath:~-4%"==".jpg" if /i not "%imagePath:~-4%"==".gif" if /i not "%imagePath:~-5%"==".jpeg" (
     echo 输入的图片格式不正确，请确保图片文件名以.png或.jpg结尾或.gif
     goto input_image
 )

:input_zip
echo 请输入一个ZIP或RAR压缩包的路径（可直接通过拖动文件放入），并以回车结束：
set /p zipPath=

if not exist "%zipPath%" (
    echo 压缩包路径不存在，请检查后重试。
    goto input_zip
)

if /i not "%zipPath:~-4%"==".zip" if /i not "%zipPath:~-4%"==".rar" (
    echo 输入的压缩包格式不正确，请确保是ZIP或RAR格式。
    goto input_zip
)

:input_species_name
echo 请输入图种名称（可选，如果不输入直接回车则使用压缩包名称）
set /p speciesName=
if "%speciesName%"=="" (
    for %%f in ("%zipPath%") do set "speciesName=%%~nf"
)

REM 自动获取图片后缀作为图种文件后缀
for %%f in ("%imagePath%") do set "speciesSuffix=%%~xf"

echo 正在生成图种文件...
set "outputFile=图种_%speciesName%%speciesSuffix%"
copy /b "%imagePath%" + "%zipPath%" "%outputFile%" >nul 2>&1
if errorlevel 1 (
    echo 生成图种文件失败，请检查路径和权限。
    exit /b
)   
echo 图种文件已在脚本所在路径下生成：%outputFile%

echo 继续制作图种输入Y，退出输入N：
set /p continueChoice=
if /i "%continueChoice%"=="Y" (
    goto input_image
) else (
    echo 退出脚本。
    exit /b
)

pause